From: Chris Hanson <org/chris-hanson/cph>
Date: Wed, 27 Nov 2002 03:15:21 +0000 (+0000)
Subject: Update to autoconf 2.5.
X-Git-Tag: 20090517-FFI~2122
X-Git-Url: https://birchwood-abbey.net/git?a=commitdiff_plain;h=21fb4dd5daec88b1fe2c5dc3f30fa309df4e676d;p=mit-scheme.git
Update to autoconf 2.5.
---
diff --git a/v7/doc/configure.ac b/v7/doc/configure.ac
new file mode 100644
index 000000000..71732bae9
--- /dev/null
+++ b/v7/doc/configure.ac
@@ -0,0 +1,89 @@
+dnl Process this file with autoconf to produce a configure script.
+
+AC_INIT([MIT Scheme documentation],
+ [7.7.2pre],
+ [bug-cscheme@zurich.ai.mit.edu],
+ [mit-scheme-doc])
+AC_REVISION([$Id: configure.ac,v 1.1 2002/11/27 03:15:21 cph Exp $])
+AC_CONFIG_SRCDIR([ref-manual/scheme.texinfo])
+
+AC_COPYRIGHT(
+[Copyright (c) 2000, 2001, 2002 Massachusetts Institute of Technology
+
+This file is part of MIT Scheme.
+
+MIT Scheme is free software; you can redistribute it and/or modify it
+under the terms of the GNU General Public License as published by the
+Free Software Foundation; either version 2 of the License, or (at your
+option) any later version.
+
+MIT Scheme is distributed in the hope that it will be useful, but
+WITHOUT ANY WARRANTY; without even the implied warranty of
+MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+General Public License for more details.
+
+You should have received a copy of the GNU General Public License
+along with MIT Scheme; if not, write to the Free Software Foundation,
+Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
+])
+
+AC_PROG_INSTALL
+AC_PROG_LN_S
+AC_PROG_MAKE_SET
+if test "$(${INSTALL} --help 2> /dev/null | fgrep -e --preserve-timestamps)"
+then
+ INSTALL="${INSTALL} --preserve-timestamps"
+fi
+
+INST_TARGETS=
+
+AC_ARG_ENABLE([html],
+ [AC_HELP_STRING([--enable-html], [generate HTML documentation])])
+if test "${enable_html:-yes}" = "yes"; then
+ htmldir="${libdir}/mit-scheme/doc"
+elif test "${enable_html}" = "no"; then
+ htmldir=
+else
+ htmldir="${enable_html}"
+fi
+test "${htmldir}" = "" || INST_TARGETS="${INST_TARGETS} install-html"
+AC_SUBST([htmldir])
+
+AC_ARG_ENABLE([pdf],
+ [AC_HELP_STRING([--enable-pdf], [generate PDF documentation])])
+if test "${enable_pdf:-yes}" = "yes"; then
+ pdfdir="${libdir}/mit-scheme/doc"
+elif test "${enable_pdf}" = "no"; then
+ pdfdir=
+else
+ pdfdir="${enable_pdf}"
+fi
+test "${pdfdir}" = "" || INST_TARGETS="${INST_TARGETS} install-pdf"
+AC_SUBST([pdfdir])
+
+AC_ARG_ENABLE([ps],
+ [AC_HELP_STRING([--enable-ps], [generate Postscript documentation])])
+if test "${enable_ps:-yes}" = "yes"; then
+ psdir="${libdir}/mit-scheme/doc"
+elif test "${enable_ps}" = "no"; then
+ psdir=
+else
+ psdir="${enable_ps}"
+fi
+test "${psdir}" = "" || INST_TARGETS="${INST_TARGETS} install-ps"
+AC_SUBST([psdir])
+
+AC_SUBST([INST_TARGETS])
+
+for D in ref-manual sos user-manual; do
+ test -L "${D}/gfdl.texinfo" \
+ || (cd "${D}"; ${LN_S} ../imail/gfdl.texinfo .)
+done
+
+AC_CONFIG_FILES([
+ Makefile
+ imail/Makefile
+ ref-manual/Makefile
+ sos/Makefile
+ user-manual/Makefile])
+AC_OUTPUT
diff --git a/v7/doc/configure.in b/v7/doc/configure.in
deleted file mode 100644
index 6a45af4b8..000000000
--- a/v7/doc/configure.in
+++ /dev/null
@@ -1,73 +0,0 @@
-dnl Process this file with autoconf to produce a configure script.
-
-dnl Copyright (c) 2000-2001 Massachusetts Institute of Technology
-dnl
-dnl This program is free software; you can redistribute it and/or
-dnl modify it under the terms of the GNU General Public License as
-dnl published by the Free Software Foundation; either version 2 of the
-dnl License, or (at your option) any later version.
-dnl
-dnl This program is distributed in the hope that it will be useful,
-dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
-dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
-dnl General Public License for more details.
-dnl
-dnl You should have received a copy of the GNU General Public License
-dnl along with this program; if not, write to the Free Software
-dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
-dnl 02111-1307, USA.
-
-AC_REVISION([$Id: configure.in,v 1.5 2001/12/17 18:21:25 cph Exp $])
-AC_INIT(ref-manual/scheme.texinfo)
-
-AC_PROG_INSTALL
-AC_PROG_LN_S
-AC_PROG_MAKE_SET
-if test "$(${INSTALL} --help 2> /dev/null | fgrep -e --preserve-timestamps)"
-then
- INSTALL="${INSTALL} --preserve-timestamps"
-fi
-
-INST_TARGETS=
-
-AC_ARG_ENABLE(html, [generate HTML documentation])
-if test "${enable_html:-yes}" = "yes"; then
- htmldir="${libdir}/mit-scheme/doc"
-elif test "${enable_html}" = "no"; then
- htmldir=
-else
- htmldir="${enable_html}"
-fi
-test "${htmldir}" = "" || INST_TARGETS="${INST_TARGETS} install-html"
-AC_SUBST(htmldir)
-
-AC_ARG_ENABLE(pdf, [generate PDF documentation])
-if test "${enable_pdf:-yes}" = "yes"; then
- pdfdir="${libdir}/mit-scheme/doc"
-elif test "${enable_pdf}" = "no"; then
- pdfdir=
-else
- pdfdir="${enable_pdf}"
-fi
-test "${pdfdir}" = "" || INST_TARGETS="${INST_TARGETS} install-pdf"
-AC_SUBST(pdfdir)
-
-AC_ARG_ENABLE(ps, [generate Postscript documentation])
-if test "${enable_ps:-yes}" = "yes"; then
- psdir="${libdir}/mit-scheme/doc"
-elif test "${enable_ps}" = "no"; then
- psdir=
-else
- psdir="${enable_ps}"
-fi
-test "${psdir}" = "" || INST_TARGETS="${INST_TARGETS} install-ps"
-AC_SUBST(psdir)
-
-AC_SUBST(INST_TARGETS)
-
-for D in ref-manual sos user-manual; do
- test -L ${D}/gfdl.texinfo \
- || (cd ${D}; ${ac_cv_prog_LN_S} ../imail/gfdl.texinfo .)
-done
-
-AC_OUTPUT(Makefile imail/Makefile ref-manual/Makefile sos/Makefile user-manual/Makefile)